Kebun Pintar Sekolah

Dua hari, satu kebun

Masa ialah anggaran tanpa rehat. Cikgu boleh mengubah suai mengikut kelas.

Komputer yang tersembunyi di mana-mana

Telefon kamu ada pemproses berbilang teras. Tetapi pengawal penyaman udara, mesin basuh dan lampu isyarat hanya perlukan komputer kecil yang murah dan jimat tenaga: mikropengawal.

Untuk kebun yang melapor ke telefon, kita pilih ESP32.

Bagaimana program Arduino berjalan

Setiap program Arduino (dipanggil sketch) ada dua bahagian wajib:

void setup() {
  // berjalan SEKALI semasa papan dihidupkan
  // contoh: tetapkan pin, mulakan Serial, sambung Wi-Fi
}

void loop() {
  // berjalan BERULANG-ULANG selama-lamanya, beribu kali sesaat
  // contoh: baca sensor, buat keputusan, kawal pam
}

Kamu tidak perlu menulis kod ini sendiri hari ini, tetapi kamu mesti boleh membacanya untuk menyemak kerja Gemini.

Voltan, arus dan rintangan

Bayangkan paip air di kebun:

• Voltan (V) ialah tekanan air, iaitu daya yang menolak.
• Arus (I) ialah banyaknya air yang mengalir setiap saat.
• Rintangan (R) ialah paip yang sempit, yang menghadkan aliran.

Ketiga-tiganya dihubungkan oleh Hukum Ohm:

Mengira perintang untuk LED

LED “memakan” sebahagian voltan, dipanggil voltan hadapan (V_f). Baki voltan jatuh pada perintang:

Contoh: ESP32 (3.3 V), LED merah (2.0 V), arus 10 mA = 0.010 A:

R = 3.3 − 2.00.010 = 1.30.010 = 130 Ω

Perintang dijual dalam nilai piawai. Kita pilih nilai piawai yang sama atau lebih besar: 150 Ω atau 220 Ω (arus lebih kecil, lebih selamat, LED masih cukup terang).

Isyarat digital dan perintang tarik-naik

Isyarat digital hanya ada dua keadaan: HIGH (3.3 V) atau LOW (0 V). Butang ialah input digital.

Pin input yang tidak disambung ke mana-mana akan “terapung” dan membaca nilai rawak. Penyelesaiannya ialah perintang tarik-naik. ESP32 ada satu di dalamnya:

pinMode(BUTANG, INPUT_PULLUP);   // butang antara pin dan GND
if (digitalRead(BUTANG) == LOW) { /* ditekan */ }

Isyarat analog: membaca nilai di antara

Sensor kelembapan tanah dan sensor cahaya memberi voltan di antara 0 dan 3.3 V. ADC menukar voltan itu kepada nombor:

PWM: “analog palsu” untuk memalapkan

Pin digital hanya boleh HIGH atau LOW. Untuk memalapkan LED atau mengawal kelajuan kipas, kita tukar HIGH dan LOW dengan sangat laju. Peratus masa HIGH dipanggil kitar tugas (duty cycle).

Dalam ESP32 core 2.0.17: ledcSetup(saluran, frekuensi, resolusi) dan ledcAttachPin(pin, saluran), kemudian ledcWrite(saluran, nilai). Nyatakan versi core dalam prompt supaya Gemini guna fungsi yang betul.

Komponen Kebun Pintar

Geganti dan I2C

Aktiviti: Pelan Pin kebun

Jurutera tidak menyambung wayar secara rawak. Mereka menulis Pelan Pin dahulu, iaitu satu jadual yang menjadi kontrak antara litar, prompt dan kod.

Litar siap untuk Wokwi: kebun-diagram.json (salin ke diagram.json projek).

Prompt ialah spesifikasi

Gemini menulis kod berdasarkan apa yang kamu tulis sahaja. Ia tidak nampak litar kamu, tidak tahu versi pustaka kamu, dan akan meneka apa yang tidak dinyatakan. Setiap tekaan ialah peluang untuk pepijat.

Jurutera menulis spesifikasi. Prompt yang baik ialah spesifikasi yang ringkas, dengan lima bahagian:

Menulis keperluan yang boleh diuji

Keperluan yang baik boleh dijawab dengan lulus atau gagal. Elakkan perkataan kabur seperti “cepat”, “kering”, “kadang-kadang”.

Perhatikan K3 menggunakan dua nilai (35.0 dan 34.0). Ini dipanggil histeresis, iaitu ia mengelakkan buzzer berbunyi-berhenti tanpa henti apabila suhu berada di sekitar 35 °C.

Kekangan: menghalang tabiat buruk AI

Tanpa kekangan, kod AI selalunya “berjalan” tetapi rapuh. Kekangan yang berguna untuk projek kita:

• Versi: “ESP32 Arduino core 2.0.17. Guna ledcSetup/ledcAttachPin untuk PWM.”
• Pustaka: “Guna hanya pustaka ini: DHT sensor library, LiquidCrystal_I2C, PubSubClient, ArduinoJson v7.”
• Tidak menyekat: “Jangan guna delay() lebih 50 ms dalam loop(). Guna millis() untuk pemasaan.”
• Kebolehbacaan: “Semua pin dan ambang sebagai pemalar bernama di bahagian atas.”
• Ketahanan: “Semak jika bacaan DHT ialah NaN dan jangan guna bacaan itu.”
• Format jawapan: “Beri kod penuh dalam satu blok. Selepas kod, terangkan dalam 5 baris bagaimana ia memenuhi K1 hingga K3.”

Teknik prompt yang digunakan jurutera

Aktiviti: Pembina Spesifikasi

Aliran kerja Makmal Arduino Maya

1. Buka Makmal ESP32 dari Desktop. Untuk projek baharu, tekan 📁 Projek Baharu.
2. Litar: lukis di wokwi.com (jangan tekan Play di sana), salin tab diagram.json ke diagram.json projek. Atau guna fail litar yang cikgu beri.
3. Kod: tampal kod Gemini ke dalam sketch.ino (Ctrl+A, Ctrl+V).
4. ▶ Bina & Jalankan (F5). Simulator terbuka. Output Serial muncul di Terminal.
5. Ralat? Tekan 📋 Salin untuk Gemini, kemudian tampal dalam Gemini. Ralat dan kod disalin bersama.

Dalam simulator, klik pada DHT22 atau potensiometer untuk menukar suhu dan kelembapan tanah semasa program berjalan. Ini cara terbaik untuk menguji K1 hingga K3.

Membaca ralat compile

Mesej ralat bermula dengan sketch.ino:baris:lajur: error:. Baca baris pertama dahulu, kerana ralat lain selalunya akibat yang pertama.

Kod berjalan ≠ kod betul

AI boleh menghasilkan kod yang kelihatan meyakinkan tetapi mengandungi kesilapan halus. Sebelum menjalankan kod pada perkakasan sebenar (contohnya pam), lakukan semakan kod:

1. Pin: setiap pemalar pin sama dengan Pelan Pin?
2. Keperluan: setiap K1, K2, K3 ada dalam kod? Cari nilai ambang dan masa.
3. Pemasaan: ada delay() panjang yang membekukan program?
4. Keadaan selamat: apa berlaku jika sensor gagal (NaN)? Adakah pam boleh hidup tanpa henti?
5. Nombor ajaib: nilai seperti 3000 atau 5000 ditulis sebagai pemalar bernama?
6. Faham: bolehkah kamu terangkan setiap fungsi kepada rakan?

Aktiviti: Cari pepijat

Gemini memberi kod ini untuk K1 (“jika tanah > 3000, pam 5 saat, kemudian rehat 60 saat”). Pelan Pin: tanah GPIO 34, geganti GPIO 26.

const int TANAH = 34;
const int PAM = 27;
const int AMBANG = 3000;

void loop() {
  int t = analogRead(TANAH);
  if (t > AMBANG) {
    digitalWrite(PAM, HIGH);
    delay(5000);
    digitalWrite(PAM, LOW);
  }
}

Corak millis() yang patut kamu kenal

Kamu tidak perlu menulisnya, tetapi kenali bentuknya semasa menyemak kod Gemini:

unsigned long mulaPam = 0;
bool pamHidup = false;

void loop() {
  unsigned long kini = millis();
  if (!pamHidup && tanahKering() && kini - akhirSiram >= REHAT_MS) {
    pamHidup = true;  mulaPam = kini;  digitalWrite(PAM, HIGH);
  }
  if (pamHidup && kini - mulaPam >= SIRAM_MS) {
    pamHidup = false; akhirSiram = kini; digitalWrite(PAM, LOW);
  }
  // ...bahagian lain terus berjalan: LCD, butang, MQTT
}

Tanda-tanda kod yang baik: kini - mula >= TEMPOH (selamat walaupun millis() melimpah selepas 49 hari), dan pemboleh ubah keadaan seperti pamHidup. Ini dipanggil mesin keadaan.

Nyahpepijat seperti saintis

Nyahpepijat ialah kaedah saintifik: buat hipotesis, uji, perhatikan.

Internet of Things

IoT bermaksud benda fizikal yang bercakap melalui Internet. Kebun kita akan menghantar data ke awan, dan sesiapa yang dibenarkan boleh melihatnya.

Dalam simulator, ESP32 bersambung ke rangkaian Wokwi-GUEST (tiada kata laluan):

WiFi.begin("Wokwi-GUEST", "", 6);   // saluran 6 = sambungan lebih cepat
while (WiFi.status() != WL_CONNECTED) { delay(200); }

Dua cara bercakap: HTTP dan MQTT

Data dihantar dalam format JSON:

{"suhu": 28.5, "lembap": 65, "tanah": 3120, "pam": false}

Merancang topik MQTT

Kita guna broker awam percuma broker.hivemq.com (port 1883). Kerana ia awam, sesiapa sahaja boleh membaca topik yang diteka. Oleh itu, guna topik yang unik dan jangan hantar data peribadi.

Struktur topik bengkel: makmal/<kod sekolah>/<kumpulan>/<data>

Untuk melihat data: buka klien web MQTT (contohnya HiveMQ WebSocket Client), sambung ke broker.hivemq.com, dan langgan makmal/smk01/k3/#.

Kamu jurutera, AI pembantu

• Kamu bertanggungjawab ke atas kod yang kamu gunakan, walaupun AI yang menulisnya.
• Faham sebelum guna: jangan hantar kod yang kamu tidak boleh terangkan.
• Jujur: nyatakan “dibina dengan bantuan Gemini” dalam laporan dan pembentangan.
• Privasi: jangan masukkan data peribadi, kata laluan atau maklumat sekolah yang sulit ke dalam prompt.
• Sahkan: AI boleh salah dengan yakin. Uji setiap keperluan.
• Keselamatan fizikal: kod yang mengawal pam, motor atau pemanas mesti ada had masa dan keadaan selamat.

Projek akhir: Kebun Pintar Sekolah

Taklimat: bina sistem yang menjaga kebun sekolah semasa hujung minggu dan melapor keadaannya. Pasukan 3 hingga 4 orang, 2 jam.

Peranan pasukan: Jurutera Perkakasan (litar, Pelan Pin) · Jurutera Spesifikasi (prompt, keperluan) · Penguji (ujian, semakan kod) · Pembentang (demo, log).

Hasil kerja dan rubrik

1. Pelan Pin dan diagram.json.
2. Log prompt: setiap prompt yang digunakan, dan apa yang berubah selepasnya.
3. Kod akhir dengan komen.
4. Jadual ujian: setiap keperluan, langkah ujian, lulus/gagal.
5. Demo 3 minit dalam simulator, termasuk satu keadaan gagal yang dikendalikan dengan selamat.

Jadual ujian pasukan

Apa yang kamu bawa pulang

• Hukum Ohm untuk mengira perintang, dan had arus pin ESP32.
• Digital, analog (ADC 12-bit, guna ADC1 dengan Wi-Fi) dan PWM.
• Pelan Pin sebagai kontrak antara litar, prompt dan kod.
• Prompt sebagai spesifikasi: konteks, perkakasan, keperluan, kekangan, ujian.
• Semak kod AI: pin, keperluan, millis(), keadaan selamat, kefahaman.
• IoT dengan Wi-Fi, HTTP, JSON dan MQTT, dengan privasi dalam fikiran.
• Kamu jurutera, AI pembantu. Tanggungjawab tetap pada kamu.

Seterusnya: cuba bina kebun ini dengan perkakasan sebenar. Kod yang sama boleh dimuat naik ke ESP32 sebenar.

Jadual dan persediaan

Kod rujukan: Kebun Pintar (tahap sasaran + MQTT)

Sudah diuji dengan pengkompil Makmal Arduino Maya (ESP32 core 2.0.17). Gunakan untuk menilai kod pasukan, bukan untuk diedarkan sebelum projek.

#include <WiFi.h>
#include <PubSubClient.h>
#include <ArduinoJson.h>
#include <DHT.h>
#include <LiquidCrystal_I2C.h>

const int PIN_DHT = 15, PIN_TANAH = 34, PIN_LDR = 35;
const int PIN_BUTANG = 4, PIN_PAM = 26, PIN_BUZZER = 25;
const int AMBANG_TANAH = 3000;             // lebih besar = lebih kering
const float SUHU_PANAS = 35.0, SUHU_OK = 34.0;
const unsigned long SIRAM_MS = 5000, REHAT_MS = 60000;
const unsigned long BACA_MS = 2000, TERBIT_MS = 10000;
const char* TOPIK = "makmal/smk01/k3/kebun";

DHT dht(PIN_DHT, DHT22);
LiquidCrystal_I2C lcd(0x27, 16, 2);
WiFiClient wifi;
PubSubClient mqtt(wifi);

float suhu = NAN, lembap = NAN;
int tanah = 0;
bool pamHidup = false, amaran = false;
unsigned long mulaPam = 0, akhirSiram = 0, akhirBaca = 0, akhirTerbit = 0, akhirBunyi = 0;
int butangLepas = HIGH; unsigned long masaButang = 0;

void mulaSiram(unsigned long kini) {
  pamHidup = true; mulaPam = kini; digitalWrite(PIN_PAM, HIGH);
  Serial.println("Pam ON");
}

void sambungMqtt() {
  if (mqtt.connected()) return;
  String id = "makmal-" + String((uint32_t)ESP.getEfuseMac(), HEX);
  if (mqtt.connect(id.c_str())) Serial.println("MQTT bersambung");
}

void setup() {
  Serial.begin(115200);
  pinMode(PIN_BUTANG, INPUT_PULLUP);
  pinMode(PIN_PAM, OUTPUT);
  dht.begin();
  lcd.init(); lcd.backlight();
  WiFi.begin("Wokwi-GUEST", "", 6);
  while (WiFi.status() != WL_CONNECTED) { delay(200); Serial.print("."); }
  mqtt.setServer("broker.hivemq.com", 1883);
  Serial.println("\nKebun sedia");
}

void loop() {
  unsigned long kini = millis();
  sambungMqtt();
  mqtt.loop();

  if (kini - akhirBaca >= BACA_MS) {                 // K2: baca dan papar
    akhirBaca = kini;
    float s = dht.readTemperature(), l = dht.readHumidity();
    if (!isnan(s) && !isnan(l)) { suhu = s; lembap = l; }
    tanah = analogRead(PIN_TANAH);
    lcd.setCursor(0, 0); lcd.printf("S:%4.1fC L:%3.0f%% ", suhu, lembap);
    lcd.setCursor(0, 1); lcd.printf("Tanah:%4d %s ", tanah, pamHidup ? "PAM" : "   ");
  }

  if (!pamHidup && tanah > AMBANG_TANAH && kini - akhirSiram >= REHAT_MS) mulaSiram(kini);   // K1
  int b = digitalRead(PIN_BUTANG);                   // siram manual, nyahlantun 50 ms
  if (b != butangLepas && kini - masaButang > 50) {
    masaButang = kini; butangLepas = b;
    if (b == LOW && !pamHidup) mulaSiram(kini);
  }
  if (pamHidup && kini - mulaPam >= SIRAM_MS) {
    pamHidup = false; akhirSiram = kini; digitalWrite(PIN_PAM, LOW);
    Serial.println("Pam OFF");
  }

  if (!isnan(suhu)) {                                // K3: amaran dengan histeresis
    if (suhu >= SUHU_PANAS) amaran = true;
    if (suhu < SUHU_OK) amaran = false;
  }
  if (amaran && kini - akhirBunyi >= 5000) { akhirBunyi = kini; tone(PIN_BUZZER, 2000, 200); }

  if (kini - akhirTerbit >= TERBIT_MS && mqtt.connected()) {   // cabaran: MQTT
    akhirTerbit = kini;
    JsonDocument doc;
    doc["suhu"] = suhu; doc["lembap"] = lembap; doc["tanah"] = tanah;
    doc["cahaya"] = analogRead(PIN_LDR); doc["pam"] = pamHidup;
    char buf[160]; serializeJson(doc, buf);
    mqtt.publish(TOPIK, buf);
    Serial.println(buf);
  }
}

Semua halaman